FAQ.How to compare two pictures?
Feedback.

Answer: You can try this code:
Example:

Function ComparePictures(p as picture,q as picture) As integer
  dim r,u as RGBSurface
  dim x,y,n,m,h,w as integer
  dim w1,w2,h1,h2,d1,d2 as integer
  dim c1,c2 as color
  
  h1=p.Height
  h2=q.Height
  w1=p.Width
  w2=q.Width
  d1=p.Depth
  d2=q.Depth
  
  if d1<>d2 then
    Return 1
  elseif w1<>w2 then
    return 2
  elseif h1<>h2 then
    Return 3
  else
    r=p.RGBSurface
    u=q.RGBSurface
    
    if r=nil or u=nil then
      Return -1
    else
      h=h1-1
      w=w1-1
      m=min(w,h)
      
      for n=0 to m
        c1=r.Pixel(n,n)
        c2=u.Pixel(n,n)
        if c1<>c2 then
          Return 4
        end if
      next
      
      for y=0 to h
        for x=0 to w
          c1=r.Pixel(x,y)
          c2=u.Pixel(x,y)
          if c1<>c2 then
            Return 5
          end if
        next
      next
      
      // 0 for equal
      // -1 for error (no RGBsurface)
      // 1 for different depth
      // 2 for different width
      // 3 for different height
      // 4 for different pixels (fast test)
      // 5 for different pixels (slow test)
    end if
  end if
  
  Exception
  Return -1
End Function

Notes: Remember that this only works on bitmap pictures, so the picture.BitmapMBS function may be useful.